EclipseWtpComponent

Enables fine-tuning wtp component details of the Eclipse plugin

Example of use with a blend of all possible properties. Bear in mind that usually you don't have configure them directly because Gradle configures it for free!

apply plugin: 'java'
apply plugin: 'war'
apply plugin: 'eclipse-wtp'

configurations {
  someInterestingConfiguration
  anotherConfiguration
}

eclipse {

  //if you want parts of paths in resulting file(s) to be replaced by variables (files):
  pathVariables 'GRADLE_HOME': file('/best/software/gradle'), 'TOMCAT_HOME': file('../tomcat')

  wtp {
    component {
      //you can configure the context path:
      contextPath = 'someContextPath'

      //you can configure the deployName:
      deployName = 'killerApp'

      //you can alter the wb-resource elements. sourceDirs is a ConventionProperty.
      //non-existing source dirs won't be added to the component file.
      sourceDirs += file('someExtraFolder')

      //you can alter the files are to be transformed into dependent-module elements:
      plusConfigurations += [ configurations.someInterestingConfiguration ]

      //or whose files are to be excluded from dependent-module elements:
      minusConfigurations += configurations.anotherConfiguration

      //you can add a wb-resource elements; mandatory keys: 'sourcePath', 'deployPath':
      //if sourcePath points to non-existing folder it will *not* be added.
      resource sourcePath: 'extra/resource', deployPath: 'deployment/resource'

      //you can add a wb-property elements; mandatory keys: 'name', 'value':
      property name: 'moodOfTheDay', value: ':-D'
    }
  }
}

For tackling edge cases users can perform advanced configuration on resulting XML file. It is also possible to affect the way eclipse plugin merges the existing configuration via beforeMerged and whenMerged closures.

beforeMerged and whenMerged closures receive WtpComponent object

Examples of advanced configuration:

apply plugin: 'java'
apply plugin: 'war'
apply plugin: 'eclipse-wtp'

eclipse {

  wtp {
    component {
      file {
        //if you want to mess with the resulting XML in whatever way you fancy
        withXml {
          def node = it.asNode()
          node.appendNode('xml', 'is what I love')
        }

        //closure executed after wtp component file content is loaded from existing file
        //but before gradle build information is merged
        beforeMerged { wtpComponent ->
          //tinker with WtpComponent here
        }

        //closure executed after wtp component file content is loaded from existing file
        //and after gradle build information is merged
        whenMerged { wtpComponent ->
          //you can tinker with the WtpComponent here
        }
      }
    }
  }
}